ຟັງຊັນຂໍ້ມູນ

ໝວດໝູນີ້ປະກອບດ້ວຍຟັງຊັນ ຂໍ້ມູນ.

ເພື່ອເຂົ້າເຖິງຄຳສັ່ງນີ້...

ແຊກ - ຟັງຊັນ - ໝວດໝູ່ ຂໍ້ມູນຂ່າວສານ

ຂໍ້ມູນໃນຕາຕະລາງຕໍ່ໄປນີ້ແມ່ນໃຊ້ເປັນພື້ນຖານສໍາລັບບາງຕົວຢ່າງໃນຄໍາອະທິບາຍຟັງຊັນ:

	C	D
2	ຄ່າ x	ຄ່າ y
3	-5	-3
4	-2	0
5	-1	1
6	0	3
7	2	4
8	4	6
9	6	8

CELL

ສົ່ງຄືນຂໍ້ມູນກ່ຽວກັບທີ່ຢູ່, ການຈັດຮູບແບບ ຫຼື ເນື້ອໃນຂອງຫ້ອງ.

ໄວຍາກອນ

CELL("InfoType" [; Reference])

InfoType ແມ່ນຂໍ້ຄວາມທີ່ລະບຸປະເພດຂອງຂໍ້ມູນ. ຂໍ້ຄວາມນີ້ເປັນພາສາອັງກິດສະເໝີ. ສາມາດໃຊ້ຕົວພິມໃຫຍ່ ຫຼື ຕົວພິມນ້ອຍກໍໄດ້.

InfoType	ຄວາມໝາຍ
COL	ສົ່ງຄືນເລກລໍາດັບຂອງຖັນທີ່ຖືກອ້າງອີງ. =CELL("COL";D2) ສົ່ງຄືນຄ່າ 4.
ROW	ສົ່ງຄືນເລກລໍາດັບຂອງແຖວທີ່ຖືກອ້າງອີງ. =CELL("ROW";D2) ສົ່ງຄືນຄ່າ 2.
SHEET	ສົ່ງຄືນເລກລໍາດັບຂອງແຜ່ນງານທີ່ຖືກອ້າງອີງ. =CELL("Sheet";Sheet3.D2) ສົ່ງຄືນຄ່າ 3.
ADDRESS	ສົ່ງຄືນທີ່ຢູ່ແບບສໍາບູນ (absolute address) ຂອງຫ້ອງທີ່ຖືກອ້າງອີງ. =CELL("ADDRESS";D2) ສົ່ງຄືນຄ່າ $D$2. =CELL("ADDRESS";Sheet3.D2) ສົ່ງຄືນຄ່າ $Sheet3.$D$2. =CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) ສົ່ງຄືນຄ່າ 'file:///X:/dr/test.ods'#$Sheet1.$D$2.
FILENAME	ສົ່ງຄືນຊື່ໄຟລ໌ ແລະ ເລກແຜ່ນງານຂອງຫ້ອງທີ່ຖືກອ້າງອີງ. =CELL("FILENAME";D2) ສົ່ງຄືນ 'file:///X:/dr/own.ods'#$Sheet1, ຫາກສູດໃນເອກະສານປັດຈຸບັນ X:\dr\own.ods ຕັ້ງຢູ່ໃນ Sheet1. =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) ສົ່ງຄືນຄ່າ 'file:///X:/dr/test.ods'#$Sheet1.
COORD	ສົ່ງຄືນທີ່ຢູ່ຫ້ອງແບບເຕັມໃນຮູບແບບຂອງ Lotus™. =CELL("COORD"; D2) ສົ່ງຄືນຄ່າ $A:$D$2. =CELL("COORD"; Sheet3.D2) ສົ່ງຄືນຄ່າ $C:$D$2.
CONTENTS	ສົ່ງຄືນເນື້ອໃນຂອງຫ້ອງທີ່ຖືກອ້າງອີງ, ໂດຍບໍ່ມີການຈັດຮູບແບບໃດໆ.
TYPE	ສົ່ງຄືນປະເພດເນື້ອໃນຂອງຫ້ອງ. b = blank (ຫວ່າງ). ຫ້ອງຫວ່າງ l = label (ປ້າຍຊື່). ຂໍ້ຄວາມ, ຜົນລັດຂອງສູດທີ່ເປັນຂໍ້ຄວາມ v = value (ຄ່າ). ຄ່າຕົວເລກ, ຜົນລັດຂອງສູດທີ່ເປັນຕົວເລກ
WIDTH	ສົ່ງຄືນຄວາມກວ້າງຂອງຖັນທີ່ຖືກອ້າງອີງ. ຫົວໜ່ວຍແມ່ນຈໍານວນຂອງເລກສູນ (0) ທີ່ສາມາດບັນຈຸລົງໃນຖັນນັ້ນໄດ້ ຕາມຮູບແບບຂໍ້ຄວາມ ແລະ ຂະໜາດເລີ່ມຕົ້ນ.
PREFIX	ສົ່ງຄືນການຈັດວາງ (alignment) ຂອງຫ້ອງທີ່ຖືກອ້າງອີງ. ' = ຈັດວາງທາງຊ້າຍ " = ຈັດວາງທາງຂວາ ^ = ຈັດວາງໄວ້ກາງ \ = ເຮັດຊໍ້າ (ປັດຈຸບັນຍັງບໍ່ທັນໃຊ້ງານ)
PROTECT	ສົ່ງຄືນສະຖານະການປ້ອງກັນຫ້ອງ. 1 = ຫ້ອງຖືກປ້ອງກັນ 0 = ຫ້ອງບໍ່ໄດ້ຖືກປ້ອງກັນ
FORMAT	ສົ່ງຄືນຂໍ້ຄວາມທີ່ລະບຸຮູບແບບຕົວເລກ. , = ຕົວເລກທີ່ມີເຄື່ອງໝາຍຂັ້ນຫຼັກພັນ F = ຕົວເລກທີ່ບໍ່ມີເຄື່ອງໝາຍຂັ້ນຫຼັກພັນ C = ຮູບແບບເງິນຕາ S = ຮູບແບບເລກກໍາລັງ (exponential), ຕົວຢ່າງ: 1.234+E56 P = ເປີເຊັນ ໃນຮູບແບບຂ້າງເທິງ, ຈໍານວນຕໍາແໜ່ງທົດສະນິຍົມຫຼັງຈຸດຈະຖືກສະແດງເປັນຕົວເລກ. ຕົວຢ່າງ: ຮູບແບບຕົວເລກ #,##0.0 ຈະສົ່ງຄືນ ,1 ແລະ ຮູບແບບຕົວເລກ 00.000% ຈະສົ່ງຄືນ P3 D1 = MMM-D-YY, MM-D-YY ແລະ ຮູບແບບທີ່ຄ້າຍຄືກັນ D2 = DD-MM D3 = MM-YY D4 = DD-MM-YYYY HH:MM:SS D5 = MM-DD D6 = HH:MM:SS AM/PM D7 = HH:MM AM/PM D8 = HH:MM:SS D9 = HH:MM G = ຮູບແບບອື່ນໆທັງໝົດ - (ລົບ) ຢູ່ທ້າຍ = ຕົວເລກລົບຈະຖືກຈັດຮູບແບບເປັນສີ () (ວົງເລັບ) ຢູ່ທ້າຍ = ມີວົງເລັບເປີດຢູ່ໃນລະຫັດຮູບແບບ
COLOR	ສົ່ງຄືນ 1, ຖ້າຄ່າລົບຖືກຈັດຮູບແບບເປັນສີ, ຖ້າບໍ່ດັ່ງນັ້ນແມ່ນ 0.
PARENTHESES	ສົ່ງຄືນ 1 ຖ້າລະຫັດຮູບແບບມີວົງເລັບເປີດ (, ຖ້າບໍ່ດັ່ງນັ້ນແມ່ນ 0.

ການອ້າງອີງ (ລາຍການຕົວເລືອກ) ແມ່ນຕຳແໜ່ງຂອງເຊວທີ່ຈະກວດສອບ. ຖ້າ ການອ້າງອີງ ແມ່ນເປັນຊ່ວງ, ເຊວຈະຍ້າຍໄປທີ່ດ້ານເທິງຊ້າຍຂອງຊ່ວງ. ຖ້າ ການອ້າງອີງ ຫາຍໄປ, LibreOffice Calc ຈະໃຊ້ຕຳແໜ່ງຂອງເຊວທີ່ສູດນີ້ຕັ້ງຢູ່. Microsoft Excel ຈະໃຊ້ການອ້າງອີງຂອງເຊວທີ່ເຄີເຊີວາງຢູ່.

CURRENT

ຟັງຊັນນີ້ສົ່ງຄືນຜົນລັດທີ່ໄດ້ມາຮອດປັດຈຸບັນ ຈາກການປະເມີນສູດທີ່ມັນເປັນສ່ວນໜຶ່ງ (ເວົ້າອີກຢ່າງໜຶ່ງແມ່ນຜົນລັດເທົ່າທີ່ການປະເມີນນັ້ນມາຮອດ). ການນໍາໃຊ້ຫຼັກແມ່ນໃຊ້ຮ່ວມກັບຟັງຊັນ STYLE() ເພື່ອກໍານົດຮູບແບບໃຫ້ກັບຫ້ອງ ໂດຍຂຶ້ນກັບເນື້ອໃນຂອງຫ້ອງນັ້ນ.

ໄວຍາກອນ

CURRENT()

ຕົວຢ່າງ

=1+2+CURRENT()

ຕົວຢ່າງນີ້ສົ່ງຄືນຄ່າ 6. ສູດຖືກຄິດໄລ່ຈາກຊ້າຍຫາຂວາດັ່ງນີ້: 1 + 2 ເທົ່າກັບ 3, ເຊິ່ງເປັນຜົນລັດມາຮອດບ່ອນທີ່ມີ CURRENT(); ດັ່ງນັ້ນ CURRENT() ຈຶ່ງມີຄ່າເທົ່າກັບ 3, ແລ້ວນໍາມາບວກກັບ 3 ທີ່ມີຢູ່ແລ້ວ ຈຶ່ງໄດ້ຜົນລັດເປັນ 6.

=A2+B2+STYLE(IF(CURRENT()>10;"Red";"Default"))

ຕົວຢ່າງນີ້ສົ່ງຄືນ A2 + B2 (STYLE ສົ່ງຄືນ 0 ໃນນີ້). ຖ້າຜົນບວກນີ້ຫຼາຍກວ່າ 10, ຮູບແບບ Red ຈະຖືກນໍາໃຊ້ກັບຫ້ອງນັ້ນ. ເບິ່ງຄໍາອະທິບາຍເພີ່ມເຕີມໃນຟັງຊັນ STYLE.

="choo"&CURRENT()

ຕົວຢ່າງນີ້ສົ່ງຄືນ choochoo.

ຂໍ້ມູນທາງເຕັກນິກ

ຟັງຊັນນີ້ ບໍ່ແມ່ນ ສ່ວນໜຶ່ງຂອງມາດຕະຖານ Open Document Format for Office Applications (OpenDocument) ເວີຊັນ 1.3 ພາກທີ 4: ຮູບແບບສູດທີ່ຄິດໄລ່ຄືນໃໝ່ (OpenFormula). ຊື່ພື້ນທີ່ (name space) ແມ່ນ

ORG.OPENOFFICE.CURRENT

FORMULA

ສະແດງສູດຂອງຫ້ອງທີ່ມີສູດ ໃຫ້ເປັນຂໍ້ຄວາມ.

ຟັງຊັນນີ້ຈະຖືກຄຳນວນຄືນໃໝ່ທຸກຄັ້ງເມື່ອມີການຄຳນວນເກີດຂຶ້ນ.

ໄວຍາກອນ

FORMULA(Reference)

Reference ແມ່ນການອ້າງອີງຫາຫ້ອງທີ່ມີສູດ.

ການອ້າງອີງທີ່ບໍ່ຖືກຕ້ອງ ຫຼື ການອ້າງອີງຫາຫ້ອງທີ່ບໍ່ມີສູດ ຈະສົ່ງຜົນໃຫ້ເກີດຄ່າຜິດພາດ #N/A.

ຕົວຢ່າງ

ຖ້າຫ້ອງ A8 ມີສູດ =SUM(1;2;3) ແລ້ວ

=FORMULA(A8) ສົ່ງຄືນຂໍ້ຄວາມ =SUM(1;2;3).

IFERROR

ສົ່ງຄືນຄ່າຫາກຫ້ອງນັ້ນບໍ່ມີຄ່າຜິດພາດ, ຫຼື ສົ່ງຄືນຄ່າທາງເລືອກຫາກມີຄ່າຜິດພາດ.

ຟັງຊັນນີ້ມີໃຫ້ໃຊ້ຕັ້ງແຕ່ LibreOffice 4.0.

ໄວຍາກອນ

IFERROR(Value; Alternate_value)

Value ແມ່ນຄ່າ ຫຼື ສໍານວນທີ່ຈະຖືກສົ່ງຄືນ ຫາກມັນບໍ່ແມ່ນ ຫຼື ບໍ່ສົ່ງຜົນໃຫ້ເກີດຂໍ້ຜິດພາດ.

Alternate_value ແມ່ນຄ່າ ຫຼື ສໍານວນທີ່ຈະຖືກສົ່ງຄືນ ຫາກສໍານວນ ຫຼື ຄ່າຂອງ Value ສົ່ງຜົນໃຫ້ເກີດຂໍ້ຜິດພາດ.

ຕົວຢ່າງ

=IFERROR(C8;C9) ໂດຍທີ່ຫ້ອງ C8 ມີ =1/0 ຈະສົ່ງຄືນຄ່າຂອງ C9, ເພາະວ່າ 1/0 ແມ່ນຂໍ້ຜິດພາດ.

=IFERROR(C8;C9) ໂດຍທີ່ຫ້ອງ C8 ມີ 13 ຈະສົ່ງຄືນຄ່າ 13 (ຄ່າຂອງ C8), ເພາະມັນບໍ່ແມ່ນຂໍ້ຜິດພາດ.

IFNA

ສົ່ງຄືນຄ່າຫາກຫ້ອງນັ້ນບໍ່ມີຄ່າຜິດພາດ #N/A (ຄ່າທີ່ບໍ່ສາມາດໃຊ້ໄດ້), ຫຼື ສົ່ງຄືນຄ່າທາງເລືອກຫາກມີຄ່າຜິດພາດນັ້ນ.

ຟັງຊັນນີ້ມີໃຫ້ໃຊ້ຕັ້ງແຕ່ LibreOffice 4.0.

ໄວຍາກອນ

IFNA(Value; Alternate_value)

Value ແມ່ນຄ່າ ຫຼື ສໍານວນທີ່ຈະຖືກສົ່ງຄືນ ຫາກມັນບໍ່ແມ່ນ ຫຼື ບໍ່ສົ່ງຜົນໃຫ້ເກີດຂໍ້ຜິດພາດ #N/A.

Alternate_value ແມ່ນຄ່າ ຫຼື ສໍານວນທີ່ຈະຖືກສົ່ງຄືນ ຫາກສໍານວນ ຫຼື ຄ່າຂອງ Value ສົ່ງຜົນໃຫ້ເກີດຂໍ້ຜິດພາດ #N/A.

ຕົວຢ່າງ

=IFNA(D3;D4) ຈະສົ່ງຄືນຄ່າຂອງ D3 ຫາກ D3 ບໍ່ສົ່ງຜົນໃຫ້ເກີດຂໍ້ຜິດພາດ #N/A, ຫຼື ສົ່ງຄືນ D4 ຫາກມີຂໍ້ຜິດພາດນັ້ນ.

INFO

ສົ່ງຄືນຂໍ້ມູນສະເພາະກ່ຽວກັບສະພາບແວດລ້ອມການເຮັດວຽກປັດຈຸບັນ. ຟັງຊັນນີ້ຮັບອາກິວເມັນເປັນຂໍ້ຄວາມດຽວ ແລະ ສົ່ງຄືນຂໍ້ມູນຂຶ້ນກັບພາຣາມິເຕີນັ້ນ.

ຟັງຊັນນີ້ຈະຖືກຄຳນວນຄືນໃໝ່ທຸກຄັ້ງເມື່ອມີການຄຳນວນເກີດຂຶ້ນ.

ໄວຍາກອນ

INFO("Type")

ຕາຕະລາງຕໍ່ໄປນີ້ສະແດງລາຍການຄ່າສໍາລັບພາຣາມິເຕີຂໍ້ຄວາມ Type ແລະ ຄ່າທີ່ສົ່ງຄືນຂອງຟັງຊັນ INFO.

ຄ່າສໍາລັບ "Type"	ຄ່າທີ່ສົ່ງຄືນ
"osversion"	ເປັນ "Windows (32-bit) NT 5.01" ສະເໝີ, ເພື່ອເຫດຜົນດ້ານຄວາມເຂົ້າກັນໄດ້
"system"	ປະເພດຂອງລະບົບປະຕິບັດການ: "ANDROID" ສໍາລັບລະບົບປະຕິບັດການມືຖືຂອງ Google "DRAGONFLY" ສໍາລັບລະບົບປະຕິບັດການ DragonFly ທີ່ແຍກມາຈາກ FreeBSD "EMSCRIPTEN" ສໍາລັບລະບົບ WebAssembly ໃນບຣາວເຊີ "FREEBSD", "OPENBSD" ຫຼື "NETBSD" ສໍາລັບລະບົບປະຕິບັດການທີ່ອີງໃສ່ Berkeley Software Distribution (BSD) "HAIKU" ສໍາລັບລະບົບປະຕິບັດການທີ່ເຂົ້າກັນໄດ້ກັບ BeOS "iOS" ສໍາລັບລະບົບປະຕິບັດການມືຖືຂອງ Apple "LINUX" ສໍາລັບລະບົບປະຕິບັດການທີ່ອີງໃສ່ GNU/Linux "MACOSX" ສໍາລັບ Apple macOS "SOLARIS" ສໍາລັບລະບົບປະຕິບັດການ Oracle Solaris "WNT" ສໍາລັບ Microsoft Windows
"release"	ຕົວລະບຸລຸ້ນຂອງຜະລິດຕະພັນ, ຕົວຢ່າງ "300m25(Build:9876)"
"numfile"	ເປັນ 1 ສະເໝີ, ເພື່ອເຫດຜົນດ້ານຄວາມເຂົ້າກັນໄດ້
"recalc"	ໂໝດການຄິດໄລ່ສູດຄືນໃໝ່ໃນປັດຈຸບັນ, ອາດເປັນ "Automatic" ຫຼື "Manual" (ແປຕາມພາສາຂອງ LibreOffice)

ແອັບພລິເຄຊັນສະເປຣດຊີດອື່ນໆ ອາດຈະຍອມຮັບຄ່າທີ່ແປແລ້ວສໍາລັບພາຣາມິເຕີ Type, ແຕ່ LibreOffice Calc ຈະຍອມຮັບສະເພາະຄ່າພາສາອັງກິດເທົ່ານັ້ນ.

ຕົວຢ່າງ

=INFO("release") ສົ່ງຄືນເລກລຸ້ນຂອງ LibreOffice ທີ່ກໍາລັງໃຊ້ງານ.

=INFO(D5) ໂດຍທີ່ຫ້ອງ D5 ມີຂໍ້ຄວາມວ່າ system ຈະສົ່ງຄືນປະເພດຂອງລະບົບປະຕິບັດການ.

ISBLANK

ສົ່ງຄືນຄ່າ TRUE ຫາກການອ້າງອີງຫາຫ້ອງນັ້ນແມ່ນຫ້ອງຫວ່າງ. ຟັງຊັນນີ້ໃຊ້ເພື່ອລະບຸວ່າເນື້ອໃນຂອງຫ້ອງນັ້ນຫວ່າງຫຼືບໍ່. ຫ້ອງທີ່ມີສູດຢູ່ທາງໃນແມ່ນບໍ່ຖືວ່າເປັນຫ້ອງຫວ່າງ.

ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຕັກກະສາດ ຫຼື ຄ່າຕົວເລກ.

ໄວຍາກອນ

ISBLANK(Value)

Value ແມ່ນເນື້ອໃນທີ່ຈະຖືກກວດສອບ.

ຕົວຢ່າງ

=ISBLANK(D2) ສົ່ງຄືນຜົນລັດເປັນ FALSE.

ISERR

ກວດສອບເງື່ອນໄຂຄວາມຜິດພາດ, ຍົກເວັ້ນຄ່າຜິດພາດ #N/A, ແລະ ສົ່ງຄືນຄ່າ TRUE ຫຼື FALSE.

ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຕັກກະສາດ ຫຼື ຄ່າຕົວເລກ.

ໄວຍາກອນ

ISERR(Value)

Value ແມ່ນຄ່າ ຫຼື ສໍານວນໃດໆ ທີ່ຖືກກວດສອບວ່າ ມີຄ່າຜິດພາດອື່ນທີ່ບໍ່ແມ່ນ #N/A ຫຼື ບໍ່.

ຕົວຢ່າງ

=ISERR(C8) ໂດຍທີ່ຫ້ອງ C8 ມີ =1/0 ຈະສົ່ງຄືນຄ່າ TRUE, ເພາະວ່າ 1/0 ແມ່ນຂໍ້ຜິດພາດ.

=ISERR(C9) ໂດຍທີ່ຫ້ອງ C9 ມີ =NA() ຈະສົ່ງຄືນຄ່າ FALSE, ເພາະ ISERR() ຈະບໍ່ສົນໃຈຂໍ້ຜິດພາດ #N/A.

ISERROR

ກວດສອບເງື່ອນໄຂຄວາມຜິດພາດ, ລວມທັງຄ່າຜິດພາດ #N/A, ແລະ ສົ່ງຄືນຄ່າ TRUE ຫຼື FALSE.

ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຕັກກະສາດ ຫຼື ຄ່າຕົວເລກ.

ໄວຍາກອນ

ISERROR(Value)

Value ແມ່ນຄ່າ ຫຼື ອ້າງອີງຫາຄ່າທີ່ຈະກວດສອບ. ISERROR() ຈະສົ່ງຄືນຄ່າ TRUE ຫາກມີຂໍ້ຜິດພາດ ແລະ FALSE ຫາກບໍ່ມີ.

ຕົວຢ່າງ

=ISERROR(C8) ໂດຍທີ່ຫ້ອງ C8 ມີ =1/0 ຈະສົ່ງຄືນຄ່າ TRUE, ເພາະວ່າ 1/0 ແມ່ນຂໍ້ຜິດພາດ.

=ISERROR(C9) ໂດຍທີ່ຫ້ອງ C9 ມີ =NA() ຈະສົ່ງຄືນຄ່າ TRUE.

ISEVEN

ສົ່ງຄືນຄ່າ TRUE ຫາກຄ່ານັ້ນແມ່ນເລກຖ້ວນຄູ່, ຫຼື FALSE ຫາກຄ່ານັ້ນແມ່ນເລກຄີກ.

ໄວຍາກອນ

ISEVEN(Value)

Value ແມ່ນຄ່າທີ່ຈະຖືກກວດສອບ.

ຫາກ Value ບໍ່ແມ່ນເລກຖ້ວນ, ຕົວເລກຫຼັງຈຸດທົດສະນິຍົມຈະຖືກລະເວັ້ນ. ເຄື່ອງໝາຍຂອງ Value ກໍຈະຖືກລະເວັ້ນເຊັ່ນກັນ.

ຕົວຢ່າງ

=ISEVEN(48) ສົ່ງຄືນຄ່າ TRUE

=ISEVEN(33) ສົ່ງຄືນຄ່າ FALSE

=ISEVEN(0) ສົ່ງຄືນຄ່າ TRUE

=ISEVEN(-2.1) ສົ່ງຄືນຄ່າ TRUE

=ISEVEN(3.999) ສົ່ງຄືນຄ່າ FALSE

ISEVEN_ADD

ກວດສອບເລກຄູ່. ສົ່ງຄືນຄ່າ 1 ຫາກຕົວເລກນັ້ນຫານໃຫ້ 2 ແລ້ວໄດ້ເລກຖ້ວນ.

ຟັງຊັນທີ່ຊື່ລົງທ້າຍດ້ວຍ _ADD ຫຼື _EXCEL2003 ຈະສົ່ງກັບຄືນຜົນລັບດຽວກັນກັບຟັງຊັນ Microsoft Excel 2003 ທີ່ກ່ຽວຂ້ອງທີ່ບໍ່ມີນາມສະກຸນນັ້ນ. ໃຊ້ຟັງຊັນທີ່ບໍ່ມີນາມສະກຸນເພື່ອໃຫ້ໄດ້ຜົນລັບຕາມມາດຕະຖານສາກົນ.

ໄວຍາກອນ

ISEVEN_ADD(Number)

Number ແມ່ນຕົວເລກທີ່ຈະຖືກກວດສອບ.

ຕົວຢ່າງ

=ISEVEN_ADD(5) ສົ່ງຄືນຄ່າ 0.

=ISEVEN_ADD(A1) ສົ່ງຄືນຄ່າ 1 ຫາກຫ້ອງ A1 ບັນຈຸຕົວເລກ 2.

ISFORMULA

ສົ່ງຄືນຄ່າ TRUE ຫາກຫ້ອງນັ້ນແມ່ນຫ້ອງທີ່ມີສູດ.

ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຕັກກະສາດ ຫຼື ຄ່າຕົວເລກ.

ໄວຍາກອນ

ISFORMULA(Reference)

Reference ລະບຸການອ້າງອີງຫາຫ້ອງທີ່ຈະຖືກກວດສອບວ່າ ມັນບັນຈຸສູດຫຼືບໍ່.

ຕົວຢ່າງ

=ISFORMULA(C4) ຈະສົ່ງຄືນຄ່າ FALSE ຫາກຫ້ອງ C4 ບັນຈຸຕົວເລກ 5.

ISLOGICAL

ກວດສອບຄ່າທາງຕັກກະສາດ (TRUE ຫຼື FALSE).

ຫາກເກີດຂໍ້ຜິດພາດ, ຟັງຊັນຈະສົ່ງຄືນຄ່າ FALSE.

ໄວຍາກອນ

ISLOGICAL(Value)

ສົ່ງຄືນຄ່າ TRUE ຫາກ Value ແມ່ນຄ່າທາງຕັກກະສາດ (TRUE ຫຼື FALSE), ແລະ ສົ່ງຄືນ FALSE ຫາກບໍ່ແມ່ນ.

ຕົວຢ່າງ

=ISLOGICAL(99) ສົ່ງຄືນຄ່າ FALSE, ເພາະວ່າ 99 ແມ່ນຕົວເລກ, ບໍ່ແມ່ນຄ່າຕັກກະສາດ.

=ISLOGICAL(ISNA(D4)) ສົ່ງຄືນຄ່າ TRUE ບໍ່ວ່າເນື້ອໃນໃນຫ້ອງ D4 ຈະແມ່ນຫຍັງກໍຕາມ, ເພາະ ISNA() ສົ່ງຄືນຄ່າທາງຕັກກະສາດ.

ISNA

ສົ່ງຄືນຄ່າ TRUE ຫາກຫ້ອງນັ້ນບັນຈຸຄ່າຜິດພາດ #N/A (ຄ່າທີ່ບໍ່ສາມາດໃຊ້ໄດ້).

ຫາກເກີດຂໍ້ຜິດພາດ, ຟັງຊັນຈະສົ່ງຄືນຄ່າ FALSE.

ໄວຍາກອນ

ISNA(Value)

Value ແມ່ນຄ່າ ຫຼື ສໍານວນທີ່ຈະຖືກກວດສອບ.

ຕົວຢ່າງ

=ISNA(D3) ສົ່ງຄືນຜົນລັດເປັນ FALSE.

ISNONTEXT

ກວດສອບວ່າເນື້ອໃນຫ້ອງແມ່ນຂໍ້ຄວາມ ຫຼື ຕົວເລກ, ແລະ ສົ່ງຄືນຄ່າ FALSE ຫາກເນື້ອໃນນັ້ນແມ່ນຂໍ້ຄວາມ.

ຫາກເກີດຂໍ້ຜິດພາດ, ຟັງຊັນຈະສົ່ງຄືນຄ່າ TRUE.

ໄວຍາກອນ

ISNONTEXT(Value)

Value ແມ່ນຄ່າ ຫຼື ສໍານວນໃດໆ ທີ່ຈະຖືກກວດສອບວ່າ ມັນແມ່ນຂໍ້ຄວາມ, ຕົວເລກ ຫຼື ຄ່າທາງຕັກກະສາດ.

ຕົວຢ່າງ

=ISNONTEXT(D2) ສົ່ງຄືນຄ່າ FALSE ຫາກຫ້ອງ D2 ບັນຈຸຂໍ້ຄວາມ abcdef.

=ISNONTEXT(D9) ສົ່ງຄືນຄ່າ TRUE ຫາກຫ້ອງ D9 ບັນຈຸຕົວເລກ 8.

ISNUMBER

ສົ່ງຄືນຄ່າ TRUE ຫາກຄ່ານັ້ນອ້າງອີງເຖິງຕົວເລກ.

ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຕັກກະສາດ ຫຼື ຄ່າຕົວເລກ.

ໄວຍາກອນ

ISNUMBER(Value)

Value ແມ່ນສໍານວນໃດໆ ທີ່ຈະຖືກກວດສອບວ່າ ມັນແມ່ນຕົວເລກ ຫຼື ຂໍ້ຄວາມ.

ຕົວຢ່າງ

=ISNUMBER(C3) ສົ່ງຄືນຄ່າ TRUE ຫາກຫ້ອງ C3 ບັນຈຸຕົວເລກ 4.

=ISNUMBER(C2) ສົ່ງຄືນຄ່າ FALSE ຫາກຫ້ອງ C2 ບັນຈຸຂໍ້ຄວາມ abcdef.

ISODD

ສົ່ງຄືນຄ່າ TRUE ຫາກຄ່ານັ້ນແມ່ນເລກຄີກ, ຫຼື FALSE ຫາກຄ່ານັ້ນແມ່ນເລກຄູ່.

ໄວຍາກອນ

ISODD(value)

Value ແມ່ນຄ່າທີ່ຈະຖືກກວດສອບ.

ຕົວຢ່າງ

=ISODD(33) ສົ່ງຄືນຄ່າ TRUE

=ISODD(48) ສົ່ງຄືນຄ່າ FALSE

=ISODD(3.999) ສົ່ງຄືນຄ່າ TRUE

=ISODD(-3.1) ສົ່ງຄືນຄ່າ TRUE

ISODD_ADD

ສົ່ງຄືນຄ່າ TRUE (1) ຫາກຕົວເລກນັ້ນຫານໃຫ້ 2 ແລ້ວບໍ່ໄດ້ເລກຖ້ວນ.

ໄວຍາກອນ

ISODD_ADD(Number)

Number ແມ່ນຕົວເລກທີ່ຈະຖືກກວດສອບ.

ຕົວຢ່າງ

=ISODD_ADD(5) ສົ່ງຄືນຄ່າ 1.

ISREF

ກວດສອບວ່າອາກິວເມັນແມ່ນການອ້າງອີງຫຼືບໍ່. ສົ່ງຄືນຄ່າ TRUE ຖ້າອາກິວເມັນແມ່ນການອ້າງອີງ, ຖ້າບໍ່ແມ່ນຈະສົ່ງຄືນ FALSE. ຟັງຊັນນີ້ຈະບໍ່ກວດສອບຄ່າທີ່ຖືກອ້າງອີງເຖິງ.

ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຕັກກະສາດ ຫຼື ຄ່າຕົວເລກ.

ໄວຍາກອນ

ISREF(Value)

Value ແມ່ນຄ່າທີ່ຈະຖືກກວດສອບວ່າແມ່ນການອ້າງອີງຫຼືບໍ່.

ຕົວຢ່າງ

=ISREF(C5) ສົ່ງຄືນຄ່າ TRUE ເພາະວ່າ C5 ແມ່ນການອ້າງອີງທີ່ຖືກຕ້ອງ.

=ISREF("abcdef") ຈະສົ່ງຄືນຄ່າ FALSE ສະເໝີ ເພາະຂໍ້ຄວາມບໍ່ສາມາດເປັນການອ້າງອີງໄດ້.

=ISREF(4) ສົ່ງຄືນຄ່າ FALSE.

=ISREF(INDIRECT("A6")) ສົ່ງຄືນຄ່າ TRUE, ເພາະວ່າ INDIRECT ແມ່ນຟັງຊັນທີ່ສົ່ງຄືນການອ້າງອີງ.

=ISREF(ADDRESS(1; 1; 2;"Sheet2")) ສົ່ງຄືນຄ່າ FALSE, ເພາະ ADDRESS ແມ່ນຟັງຊັນທີ່ສົ່ງຄືນຂໍ້ຄວາມ, ເຖິງວ່າມັນຈະເບິ່ງຄືການອ້າງອີງກໍຕາມ.

ISTEXT

ສົ່ງຄືນຄ່າ TRUE ຫາກເນື້ອໃນຫ້ອງອ້າງອີງເຖິງຂໍ້ຄວາມ.

ຫາກເກີດຂໍ້ຜິດພາດ, ຟັງຊັນຈະສົ່ງຄືນຄ່າ FALSE.

ໄວຍາກອນ

ISTEXT(Value)

Value ແມ່ນຄ່າ, ຕົວເລກ, ຄ່າທາງຕັກກະສາດ ຫຼື ຄ່າຜິດພາດທີ່ຈະຖືກກວດສອບ.

ຕົວຢ່າງ

=ISTEXT(D9) ສົ່ງຄືນຄ່າ TRUE ຫາກຫ້ອງ D9 ບັນຈຸຂໍ້ຄວາມ abcdef.

=ISTEXT(C3) ສົ່ງຄືນຄ່າ FALSE ຫາກຫ້ອງ C3 ບັນຈຸຕົວເລກ 3.

N

ສົ່ງຄືນຄ່າຕົວເລກຂອງພາຣາມິເຕີທີ່ໃຫ້ມາ. ສົ່ງຄືນ 0 ຫາກພາຣາມິເຕີແມ່ນຂໍ້ຄວາມ ຫຼື FALSE.

ຫາກເກີດຂໍ້ຜິດພາດ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຜິດພາດນັ້ນ.

ໄວຍາກອນ

N(Value)

Value ແມ່ນພາຣາມິເຕີທີ່ຈະຖືກແປງເປັນຕົວເລກ. N() ຈະສົ່ງຄືນຄ່າຕົວເລກຫາກສາມາດແປງໄດ້. ມັນຈະສົ່ງຄືນຄ່າທາງຕັກກະສາດ TRUE ເປັນ 1 ແລະ FALSE ເປັນ 0. ສໍາລັບຂໍ້ຄວາມມັນຈະສົ່ງຄືນເປັນ 0.

ຕົວຢ່າງ

=N(123) ສົ່ງຄືນຄ່າ 123

=N(TRUE()) ສົ່ງຄືນຄ່າ 1

=N(FALSE()) ສົ່ງຄືນຄ່າ 0

=N("abc") ສົ່ງຄືນຄ່າ 0

=N(1/0) ສົ່ງຄືນຄ່າ #DIV/0!

NA

ສົ່ງຄືນຄ່າຜິດພາດ #N/A.

ໄວຍາກອນ

NA()

ຕົວຢ່າງ

=NA() ປ່ຽນເນື້ອໃນຂອງຫ້ອງໃຫ້ເປັນ #N/A.

TYPE

ສົ່ງຄືນປະເພດຂອງຄ່າ, ໂດຍທີ່ 1 = ຕົວເລກ, 2 = ຂໍ້ຄວາມ, 4 = ຄ່າທາງຕັກກະສາດ, 8 = ສູດ, 16 = ຄ່າຜິດພາດ, 64 = ອາເຣ (array).

ຖ້າມີຂໍ້ຜິດພາດເກີດຂຶ້ນ, ຟັງຊັນຈະສົ່ງຄືນຄ່າຕັກກະສາດ ຫຼື ຄ່າຕົວເລກ.

ໄວຍາກອນ

TYPE(Value)

Value ແມ່ນຄ່າສະເພາະທີ່ຈະຖືກນໍາມາລະບຸປະເພດຂໍ້ມູນ.

ຕົວຢ່າງ (ເບິ່ງຕາຕະລາງຕົວຢ່າງຂ້າງເທິງ)

=TYPE(C2) ສົ່ງຄືນຜົນລັດເປັນ 2.

=TYPE(D9) ສົ່ງຄືນຜົນລັດເປັນ 1.

ຟັງຊັນຕາມໝວດໝູ່